Remove any dependencies on App from the spaces module.

Remove any dependencies on App from the spaces module. This requires moving some dialogs either to spaces, or libneochat if they're used more generically.

src/libneochat/CMakeLists.txt

@@ -51,7 +51,11 @@ ecm_add_qml_module(LibNeoChat GENERATE_PLUGIN_SOURCE
     QML_FILES
         qml/GroupChatDrawerHeader.qml
         qml/LocationMapItem.qml
+        qml/InviteUserPage.qml
+        qml/ExploreRoomsPage.qml
         qml/SearchPage.qml
+        qml/CreateRoomDialog.qml
+        qml/CreateSpaceDialog.qml
 )
 
 ecm_qt_declare_logging_category(LibNeoChat

src/libneochat/qml/CreateRoomDialog.qml

@@ -0,0 +1,73 @@
+// SPDX-FileCopyrightText: 2023 Tobias Fella <tobias.fella@kde.org>
+// SPDX-License-Identifier: GPL-2.0-only OR GPL-3.0-or-later OR LicenseRef-KDE-Accepted-GPL
+
+import QtQuick
+import QtQuick.Controls as QQC2
+import QtQuick.Layouts
+
+import org.kde.kirigami as Kirigami
+import org.kde.kirigamiaddons.formcard as FormCard
+import org.kde.kirigamiaddons.labs.components as Components
+
+import org.kde.neochat
+
+Kirigami.Dialog {
+    id: root
+
+    property string parentId
+
+    required property NeoChatConnection connection
+
+    signal newChild(string childName)
+
+    title: i18nc("@title", "Create Room")
+    implicitWidth: Kirigami.Units.gridUnit * 20
+    standardButtons: Kirigami.Dialog.Cancel
+
+    customFooterActions: [
+        Kirigami.Action {
+            icon.name: "list-add-symbolic"
+            text: i18nc("@action:button Create new room", "Create")
+            enabled: roomNameField.text.length > 0
+            onTriggered: {
+                root.connection.createRoom(roomNameField.text, "", root.parentId, false);
+                root.newChild(roomNameField.text);
+                root.close();
+            }
+        }
+    ]
+
+    Component.onCompleted: roomNameField.forceActiveFocus()
+
+    ColumnLayout {
+        spacing: Kirigami.Units.largeSpacing
+
+        FormCard.FormRadioDelegate {
+            id: privateTypeDelegate
+            text: i18nc("@info:label", "Private")
+            description: i18nc("@info:description", "This room can only be joined with an invite.")
+            checked: true
+        }
+
+        FormCard.FormRadioDelegate {
+            id: publicTypeDelegate
+            text: i18nc("@info:label", "Public")
+            description: i18nc("@info:description", "This room can be found and joined by anyone.")
+        }
+
+        FormCard.FormDelegateSeparator {}
+
+        FormCard.FormTextFieldDelegate {
+            id: roomNameField
+            label: i18nc("@info:label Name of the room", "Name:")
+            placeholderText: i18nc("@info:placeholder Placeholder for room name", "New Room")
+        }
+
+        FormCard.FormTextFieldDelegate {
+            id: roomAddressField
+            label: i18nc("@info:label Address or alias to refer to the room by", "Address:")
+            placeholderText: i18nc("@info:placeholder Placeholder address for the room", "new-room")
+            visible: publicTypeDelegate.checked
+        }
+    }
+}

src/libneochat/qml/CreateSpaceDialog.qml

@@ -0,0 +1,64 @@
+// SPDX-FileCopyrightText: 2023 Tobias Fella <tobias.fella@kde.org>
+// SPDX-License-Identifier: GPL-2.0-only OR GPL-3.0-or-later OR LicenseRef-KDE-Accepted-GPL
+
+import QtQuick
+import QtQuick.Controls as QQC2
+import QtQuick.Layouts
+
+import org.kde.kirigami as Kirigami
+import org.kde.kirigamiaddons.formcard as FormCard
+import org.kde.kirigamiaddons.labs.components as Components
+
+import org.kde.neochat
+
+Kirigami.Dialog {
+    id: root
+
+    property string parentId
+
+    required property NeoChatConnection connection
+
+    signal newChild(string childName)
+
+    title: i18nc("@title", "Create a Space")
+    implicitWidth: Kirigami.Units.gridUnit * 20
+    standardButtons: Kirigami.Dialog.Cancel
+
+    Component.onCompleted: roomNameField.forceActiveFocus()
+
+    customFooterActions: [
+        Kirigami.Action {
+            icon.name: "list-add-symbolic"
+            text: i18nc("@action:button Create new space", "Create")
+            enabled: roomNameField.text.length > 0
+            onTriggered: {
+                root.connection.createSpace(roomNameField.text, "", root.parentId, newOfficialCheck.checked);
+                root.newChild(roomNameField.text);
+                root.close();
+            }
+        }
+    ]
+
+    ColumnLayout {
+        spacing: Kirigami.Units.largeSpacing
+
+        FormCard.FormTextFieldDelegate {
+            id: roomNameField
+            label: i18nc("@info:label Name of the space", "Name:")
+            placeholderText: i18nc("@info:placeholder", "New Space")
+        }
+
+        FormCard.FormDelegateSeparator {
+            above: roomNameField
+            below: newOfficialCheck
+            visible: newOfficialCheck.visible
+        }
+
+        FormCard.FormCheckDelegate {
+            id: newOfficialCheck
+            visible: root.parentId.length > 0
+            text: i18nc("@option:check As in make the space from which this dialog was created an official parent.", "Make this parent official")
+            checked: true
+        }
+    }
+}

src/libneochat/qml/ExploreRoomsPage.qml

@@ -0,0 +1,140 @@
+// SPDX-FileCopyrightText: 2019 Black Hat <bhat@encom.eu.org>
+// SPDX-FileCopyrightText: 2020 Carl Schwan <carl@carlschwan.eu>
+// SPDX-License-Identifier: GPL-3.0-only
+
+import QtQuick
+import QtQuick.Controls as QQC2
+import QtQuick.Layouts
+import Qt.labs.qmlmodels
+
+import org.kde.kirigami as Kirigami
+import org.kde.kirigamiaddons.delegates as Delegates
+
+import org.kde.neochat
+
+/**
+ * @brief Component for finding rooms for the public list.
+ *
+ * This component is based on a SearchPage, adding the functionality to select or
+ * enter a server in the header, as well as the ability to manually type a room in
+ * if the public room search cannot find it.
+ *
+ * @sa SearchPage
+ */
+SearchPage {
+    id: root
+
+    /**
+     * @brief The connection for the current local user.
+     */
+    required property NeoChatConnection connection
+
+    /**
+     * @brief Whether results should only includes spaces.
+     */
+    property bool showOnlySpaces: spacesOnlyButton.checked
+    onShowOnlySpacesChanged: updateSearch()
+
+    /**
+     * @brief Whetherthe button to toggle the showOnlySpaces state should be shown.
+     */
+    property bool showOnlySpacesButton: true
+
+    /**
+     * @brief Signal emitted when a room is selected.
+     *
+     * The signal contains all the room's info so that it can be acted
+     * upon as required, e.g. joining or entering the room or adding the room as
+     * the child of a space.
+     */
+    signal roomSelected(string roomId, string displayName, url avatarUrl, string alias, string topic, int memberCount, bool isJoined)
+
+    title: i18nc("@action:title", "Explore Rooms")
+    customPlaceholderText: publicRoomListModel.redirectedText
+    customPlaceholderIcon: "data-warning"
+
+    Component.onCompleted: focusSearch()
+
+    headerTrailing: RowLayout {
+        QQC2.Button {
+            id: spacesOnlyButton
+            icon.name: "globe"
+            display: QQC2.Button.IconOnly
+            checkable: true
+            text: i18nc("@action:button", "Only show spaces")
+
+            QQC2.ToolTip.visible: hovered
+            QQC2.ToolTip.text: text
+            QQC2.ToolTip.delay: Kirigami.Units.toolTipDelay
+        }
+        ServerComboBox {
+            id: serverComboBox
+            connection: root.connection
+        }
+    }
+
+    model: PublicRoomListModel {
+        id: publicRoomListModel
+
+        connection: root.connection
+        server: serverComboBox.server
+        showOnlySpaces: root.showOnlySpaces
+    }
+
+    modelDelegate: ExplorerDelegate {
+        onRoomSelected: (roomId, displayName, avatarUrl, alias, topic, memberCount, isJoined) => {
+            root.roomSelected(roomId, displayName, avatarUrl, alias, topic, memberCount, isJoined);
+            root.closeDialog();
+        }
+    }
+
+    listHeaderDelegate: Delegates.RoundedItemDelegate {
+        id: delegate
+
+        onClicked: _private.openManualRoomDialog()
+
+        activeFocusOnTab: false // We handle moving to this item via up/down arrows, otherwise the tab order is wacky
+        text: i18n("Enter a Room Manually")
+        visible: publicRoomListModel.redirectedText.length === 0
+        icon.name: "compass"
+        icon.width: Kirigami.Units.gridUnit * 2
+        icon.height: Kirigami.Units.gridUnit * 2
+
+        contentItem: Kirigami.IconTitleSubtitle {
+            icon: icon.fromControlsIcon(delegate.icon)
+            title: delegate.text
+            subtitle: i18n("If you already know a room's address or alias, and it isn't shown here.")
+        }
+    }
+
+    listFooterDelegate: QQC2.ProgressBar {
+        width: ListView.view.width
+        leftInset: Kirigami.Units.largeSpacing
+        rightInset: Kirigami.Units.largeSpacing
+        visible: root.count !== 0 && publicRoomListModel.searching
+        indeterminate: true
+    }
+
+    searchFieldPlaceholder: i18n("Find a room…")
+    noResultPlaceholderMessage: i18nc("@info:label", "No public rooms found")
+
+    Component {
+        id: manualRoomDialog
+        ManualRoomDialog {}
+    }
+
+    QtObject {
+        id: _private
+        function openManualRoomDialog() {
+            let dialog = manualRoomDialog.createObject(root.QQC2.Overlay.overlay, {
+                connection: root.connection
+            });
+            dialog.parent = root.Window.window.overlay;
+            dialog.roomSelected.connect((roomId, displayName, avatarUrl, alias, topic, memberCount, isJoined) => {
+                root.roomSelected(roomId, displayName, avatarUrl, alias, topic, memberCount, isJoined);
+                root.closeDialog();
+            });
+            dialog.open();
+        }
+    }
+}

src/libneochat/qml/InviteUserPage.qml

@@ -0,0 +1,90 @@
+// SPDX-FileCopyrightText: 2019 Black Hat <bhat@encom.eu.org>
+// SPDX-License-Identifier: GPL-3.0-only
+
+pragma ComponentBehavior: Bound
+
+import QtQuick
+import QtQuick.Controls as QQC2
+import QtQuick.Layouts
+
+import org.kde.kirigami as Kirigami
+import org.kde.kirigamiaddons.delegates as Delegates
+import org.kde.kirigamiaddons.labs.components as KirigamiComponents
+
+import org.kde.neochat
+
+SearchPage {
+    id: root
+
+    property NeoChatRoom room
+
+    title: i18nc("@title:dialog", "Invite a User")
+
+    searchFieldPlaceholder: i18nc("@info:placeholder", "Find a user…")
+    noResultPlaceholderMessage: i18nc("@info:placeholder", "No users found")
+
+    headerTrailing: QQC2.Button {
+        icon.name: "list-add"
+        display: QQC2.Button.IconOnly
+        enabled: root.model.searchText.match(/@(.+):(.+)/g) && !root.room.containsUser(root.model.searchText)
+
+        text: i18nc("@action:button", "Invite this User")
+
+        QQC2.ToolTip.visible: hovered
+        QQC2.ToolTip.text: root.room.containsUser(root.model.searchText) ? i18nc("@info:tooltip", "User is either already a member or has been invited") : text
+        QQC2.ToolTip.delay: Kirigami.Units.toolTipDelay
+
+        onClicked: root.room.inviteToRoom(root.model.searchText);
+    }
+
+    model: UserDirectoryListModel {
+        id: userDictListModel
+
+        connection: root.room.connection
+    }
+
+    modelDelegate: Delegates.RoundedItemDelegate {
+        id: delegate
+
+        required property string userId
+        required property string displayName
+        required property url avatarUrl
+
+        text: displayName
+
+        contentItem: RowLayout {
+            KirigamiComponents.Avatar {
+                Layout.preferredWidth: Kirigami.Units.iconSizes.medium
+                Layout.preferredHeight: Kirigami.Units.iconSizes.medium
+                source: delegate.avatarUrl
+                name: delegate.displayName
+            }
+
+            Delegates.SubtitleContentItem {
+                itemDelegate: delegate
+                subtitle: delegate.userId
+                labelItem.textFormat: Text.PlainText
+            }
+
+            QQC2.ToolButton {
+                id: inviteButton
+
+                readonly property bool inRoom: root.room && root.room.containsUser(delegate.userId)
+
+                icon.name: "document-send"
+                text: i18nc("@action:button", "Send invitation")
+                opacity: inRoom ? 0.5 : 1
+                enabled: !inRoom
+
+                onClicked: {
+                    inviteButton.enabled = false;
+                    root.room.inviteToRoom(delegate.userId);
+                }
+
+                QQC2.ToolTip.text: !inRoom ? text : i18nc("@info:tooltip", "User is either already a member or has been invited")
+                QQC2.ToolTip.visible: inviteButton.hovered
+                QQC2.ToolTip.delay: Kirigami.Units.toolTipDelay
+            }
+        }
+    }
+}