Push Rule Model Rework

This is a significant rework of the handling of push rules. Rather than using a lot of boilerplate code for the default models `KeywordNotificationModel` has been converted to `PushRuleModel` and now handles all push rules.

The new model has the following features:
- Handles all push rules
- Has special handling for the names of default keywords (i.e. it still gives the same text as previously for showing in the settings menus)
- Push rules for blocking individuals or room overrides are still there but hidden so will be available for developer tools (to follow)
- Room specific keywords are now supported.

The notification settings pages have also been refactored to take advantage of the new models. Each section is now just a repeater with a filter for the rules that it should contain. The push rule delegate has now been cleaned up and uses required properties.

Implements network/neochat#574

src/qml/RoomSettings/PushNotification.qml

@@ -7,10 +7,12 @@ import QtQuick.Layouts 1.15
 
 import org.kde.kirigami 2.15 as Kirigami
 import org.kde.kirigamiaddons.labs.mobileform 0.1 as MobileForm
+import org.kde.kitemmodels 1.0
 
 import org.kde.neochat 1.0
 
 Kirigami.ScrollablePage {
+    id: root
 
     property NeoChatRoom room
 
@@ -62,5 +64,86 @@ Kirigami.ScrollablePage {
                 }
             }
         }
+
+        MobileForm.FormCard {
+            Layout.fillWidth: true
+
+            contentItem: ColumnLayout {
+                spacing: 0
+
+                MobileForm.FormCardHeader {
+                    title: i18n("Keywords")
+                }
+                Repeater {
+                    model: KSortFilterProxyModel {
+                        sourceModel: Controller.pushRuleModel
+
+                        filterRowCallback: function(source_row, source_parent) {
+                            let sectionRole = sourceModel.data(sourceModel.index(source_row, 0, source_parent), PushRuleModel.SectionRole)
+                            let roomIdRole = sourceModel.data(sourceModel.index(source_row, 0, source_parent), PushRuleModel.RoomIdRole)
+                            return sectionRole == PushNotificationSection.RoomKeywords && roomIdRole == root.room.id;
+                        }
+                    }
+
+                    delegate: ruleDelegate
+                }
+                MobileForm.AbstractFormDelegate {
+                    Layout.fillWidth: true
+
+                    contentItem : RowLayout {
+                        Kirigami.ActionTextField {
+                            id: keywordAddField
+
+                            Layout.fillWidth: true
+
+                            placeholderText: i18n("Keyword…")
+                            enabled: NotificationsManager.keywordNotificationAction !== PushNotificationAction.Unknown
+
+                            rightActions: Kirigami.Action {
+                                icon.name: "edit-clear"
+                                visible: keywordAddField.text.length > 0
+                                onTriggered: {
+                                    keywordAddField.text = ""
+                                }
+                            }
+
+                            onAccepted: {
+                                Controller.pushRuleModel.addKeyword(keywordAddField.text, root.room.id)
+                                keywordAddField.text = ""
+                            }
+                        }
+                        QQC2.Button {
+                            id: addButton
+
+                            text: i18n("Add keyword")
+                            Accessible.name: text
+                            icon.name: "list-add"
+                            display: QQC2.AbstractButton.IconOnly
+                            enabled: NotificationsManager.keywordNotificationAction !== PushNotificationAction.Unknown
+
+                            onClicked: {
+                                Controller.pushRuleModel.addKeyword(keywordAddField.text, root.room.id)
+                                keywordAddField.text = ""
+                            }
+
+                            QQC2.ToolTip {
+                                text: addButton.text
+                                delay: Kirigami.Units.toolTipDelay
+                            }
+                        }
+                    }
+                }
+            }
+        }
+    }
+
+    Component {
+        id: ruleDelegate
+        NotificationRuleItem {
+            onDeleteRule: {
+                Controller.pushRuleModel.removeKeyword(id)
+            }
+            onActionChanged: (action) => Controller.pushRuleModel.setPushRuleAction(id, action)
+        }
     }
 }