Message Content Rework

For now everything should look identical. However this moves to using a model for the content of the message and is intended to lay the foundation for improved message content representation, e.g. splitting up a text message in multiple sections and using different delegates for things like code and quotes.
2024-02-18 09:53:08 +00:00
parent 0ebcacce69
commit b598584aea
52 changed files with 2515 additions and 2186 deletions
--- a/src/qml/LiveLocationComponent.qml
+++ b/src/qml/LiveLocationComponent.qml
@@ -0,0 +1,92 @@
+// SPDX-FileCopyrightText: 2021 Tobias Fella <fella@posteo.de>
+// SPDX-FileCopyrightText: 2023 Volker Krause <vkrause@kde.org>
+// SPDX-FileCopyrightText: 2024 James Graham <james.h.graham@protonmail.com>
+// SPDX-License-Identifier: GPL-2.0-or-later
+
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+import QtLocation
+import QtPositioning
+
+import org.kde.neochat
+
+/**
+ * @brief A component to show a live location from a message.
+ */
+ColumnLayout {
+    id: root
+
+    /**
+     * @brief The NeoChatRoom the delegate is being displayed in.
+     */
+    required property NeoChatRoom room
+
+    /**
+     * @brief The matrix ID of the message event.
+     */
+    required property string eventId
+
+    /**
+     * @brief The display text of the message.
+     */
+    required property string display
+
+    /**
+     * @brief The maximum width that the bubble's content can be.
+     */
+    property real maxContentWidth: -1
+
+    Layout.fillWidth: true
+    Layout.maximumWidth: root.maxContentWidth
+
+    LiveLocationsModel {
+        id: liveLocationModel
+        eventId: root.eventId
+        room: root.room
+    }
+    MapView {
+        id: mapView
+        Layout.fillWidth: true
+        Layout.preferredWidth: root.maxContentWidth
+        Layout.preferredHeight: root.maxContentWidth / 16 * 9
+
+        map.center: QtPositioning.coordinate(liveLocationModel.boundingBox.y, liveLocationModel.boundingBox.x)
+        map.zoomLevel: 15
+
+        map.plugin: OsmLocationPlugin.plugin
+
+        MapItemView {
+            model: liveLocationModel
+            delegate: LocationMapItem {}
+        }
+
+        TapHandler {
+            acceptedButtons: Qt.LeftButton
+            onTapped: {
+                let map = fullScreenMap.createObject(parent, {liveLocationModel: liveLocationModel});
+                map.open()
+            }
+            onLongPressed: openMessageContext("")
+        }
+        TapHandler {
+            acceptedButtons: Qt.RightButton
+            onTapped: openMessageContext("")
+        }
+        Connections {
+            target: mapView.map
+            function onCopyrightLinkActivated() {
+                Qt.openUrlExternally(link)
+            }
+        }
+    }
+    Component {
+        id: fullScreenMap
+        FullScreenMap {}
+    }
+
+    TextComponent {
+        display: root.display
+        visible: root.display !== ""
+    }
+}