Fix the Timeline Part 1

This introduces a new base delegate that handles sizing the content of delegate in the timeline, i.e. it handles all the size helper stuff. This is then used for all the other main delegates: - messages - state - read marker This means they now all have identical base code to do the sizing (read marker still had legacy code). Because the new base delegate is called `TimelineDelegate` both `TimelineContainer` and `MessageDelegate` have been renamed: - MessageDelegate -> TextDelegate - this never made sense before images, videos, etc are all technically messages in Matrix parlance - TimelineContainer -> MessageDelegate - this has always really been the base for messages Note - this is mostly groundwork for dealing with the layout polish loop spam which will hopefully be fixed in part 2 with a bubble rework.
2023-09-21 16:26:34 +00:00
parent 69087c2117
commit e926b22524
19 changed files with 904 additions and 848 deletions
--- a/src/qml/Component/Timeline/TextDelegate.qml
+++ b/src/qml/Component/Timeline/TextDelegate.qml
@@ -0,0 +1,76 @@
+// SPDX-FileCopyrightText: 2021 Tobias Fella <tobias.fella@kde.org>
+// SPDX-License-Identifier: GPL-3.0-only
+
+import QtQuick 2.15
+import QtQuick.Layouts 1.15
+
+import Qt.labs.qmlmodels 1.0
+
+import org.kde.neochat 1.0
+
+/**
+ * @brief A timeline delegate for a text message.
+ *
+ * @inherit MessageDelegate
+ */
+MessageDelegate {
+    id: root
+
+    /**
+     * @brief The link preview properties.
+     *
+     * This is a list or object containing the following:
+     *  - url - The URL being previewed.
+     *  - loaded - Whether the URL preview has been loaded.
+     *  - title - the title of the URL preview.
+     *  - description - the description of the URL preview.
+     *  - imageSource - a source URL for the preview image.
+     *
+     * @note An empty link previewer should be passed if there are no links to
+     *       preview.
+     */
+    required property var linkPreview
+
+    /**
+     * @brief Whether there are any links to preview.
+     */
+    required property bool showLinkPreview
+
+    onOpenContextMenu: RoomManager.viewEventMenu(eventId, author, delegateType, plainText, display, label.selectedText)
+
+    innerObject: ColumnLayout {
+        Layout.maximumWidth: root.contentMaxWidth
+        RichLabel {
+            id: label
+            Layout.fillWidth: true
+            visible: currentRoom.chatBoxEditId !== root.eventId
+
+            isReply: root.isReply
+
+            textMessage: root.display
+
+            TapHandler {
+                enabled: !label.hoveredLink
+                acceptedButtons: Qt.LeftButton
+                onLongPressed: root.openContextMenu()
+            }
+        }
+        Loader {
+            Layout.fillWidth: true
+            Layout.minimumHeight: item ? item.minimumHeight : -1
+            Layout.preferredWidth: item ? item.preferredWidth : -1
+            visible: currentRoom.chatBoxEditId === root.eventId
+            active: visible
+            sourceComponent: MessageEditComponent {
+                room: currentRoom
+                messageId: root.eventId
+            }
+        }
+        LinkPreviewDelegate {
+            Layout.fillWidth: true
+            active: !currentRoom.usesEncryption && currentRoom.urlPreviewEnabled && Config.showLinkPreview && root.showLinkPreview && !root.linkPreview.empty
+            linkPreviewer: root.linkPreview
+            indicatorEnabled: root.isVisibleInTimeline()
+        }
+    }
+}